Programming in D - static foreach

`static foreach`

タプル章で、コンパイル時のforeachについて説明した。コンパイル時のforeachは、コンパイル時にループを反復し、各反復を個別のコードとして展開する。例えば、タプルを反復する次のforeachループがある。

auto t = tuple(42, "hello", 1.5);

foreach (i, member; t) {
    writefln("%s: %s", i, member);
}

コンパイラは、ループを次のような同等のコードに展開する:

{
    enum size_t i = 0;
    int member = t[i];
    writefln("%s: %s", i, member);
}
{
    enum size_t i = 1;
    string member = t[i];
    writefln("%s: %s", i, member);
}
{
    enum size_t i = 2;
    double member = t[i];
    writefln("%s: %s", i, member);
}

コンパイル時のforeachは非常に強力であるが、場合によっては、その一部の特性が適さない場合もある。

コンパイル時foreachでは、ループの展開ごとにスコープが追加される。上記のiとmember変数のように、これにより、複数のスコープでシンボルを使用しても多重定義エラーが発生しない。これは一部のケースでは望ましいが、1つの反復展開されたコードが他の反復のコードを使用できなくなる。
コンパイル時のforeachは、タプル(AliasSeqの形式のテンプレート引数を含む)でのみ機能する。例えば、次の配列リテラルの要素はコンパイル時に既知であるにもかかわらず、ループは常に実行時に実行される(これはまさに望ましい動作である場合もある)。

void main() {
    enum arr = [1, 2];
    // 実行時に実行され、コンパイル時に展開されない:
    foreach (i; arr) {
        // ...
    }
}

通常のforeachと同様に、コンパイル時のforeachは関数内でのみ使用できる。例えば、モジュールスコープやユーザー定義の型定義内では使用できない。

import std.meta;

// モジュールスコープで関数オーバーロードを定義しようとしている:
foreach (T; AliasSeq!(int, double)) {    // ← コンパイルエラー
    T twoTimes(T arg) {
        return arg * 2;
    }
}

void main() {
}

エラー: 宣言が必要、foreachではない

コンパイル時のforeachでは、ループ本体内のbreakおよびcontinue文が、コンパイル時のループの反復自体に影響を与えるのか、それとも展開されたコードの一部となるのかが明確ではない場合がある。

static foreachは、より強力なコンパイル時機能で、より詳細な制御を提供する:

static foreachは、コンパイル時に計算できるあらゆる範囲の要素(1..10のような数値範囲を含む)で使用できる。例えば、Rangesの章で説明したFibonacciSeriesの範囲と、数値が偶数であるかどうかを判断する関数がある。

static foreach (n; FibonacciSeries().take(10).filter!isEven) {
    writeln(n);
}

上記のループは、以下の同等のコードに展開される:

writeln(0);
writeln(2);
writeln(8);
writeln(34);

static foreachモジュールスコープで使用できる。
static foreach各反復に個別のスコープを導入しない。例えば、次のループは、モジュールスコープで関数の2つのオーバーロードを定義している。

import std.meta;

static foreach (T; AliasSeq!(int, double)) {
    T twoTimes(T arg) {
        return arg * 2;
    }
}

void main() {
}

上記のループは、以下の同等のコードに展開される:

int twoTimes(int arg) {
    return arg * 2;
}

double twoTimes(double arg) {
    return arg * 2;
}

break また、static foreachループ内のcontinue文は、明確にするためにラベルが必要だ。例えば、次のコードは、switch文内のcase句を展開(生成)する。各case句の下にあるbreak文は、関連するswitch文をラベルで指定する必要がある。

import std.stdio;

void main(string[] args) {

theSwitchStatement:
    switch (args.length) {
        static foreach (i; 1..3) {
            case i:
                writeln(i);
                break theSwitchStatement;
        }

    default:
        writeln("default case");
        break;
    }
}

上記のループが展開されると、switch文は次のコードと同等になる。

switch (args.length) {
case 1:
    writeln(1);
    break;

case 2:
    writeln(2);
    break;

default:
    writeln("default case");
    break;
}